//------------------------------------------------------------------------
// : TurtleTrader
// : 꽻ϵͳ
// : ʽӦ
// : ڽӦ
//------------------------------------------------------------------------

Params
    Numeric RiskRatio(1);                   // % Risk Per N ( 0 - 100)
    Numeric ATRLength(20);                  // ƽ ATR Length
    Numeric boLength(20);                   //  BreakOut Length
    Numeric fsLength(55);                   //  FailSafe Length
    Numeric teLength(10);                   //  Trailing Exit Length
    Bool LastProfitableTradeFilter(True);   // ʹй
Vars
    Numeric MinPoint;                       // С䶯λ
    NumericSeries AvgTR;                    // ATR
    Numeric N;                              // N ֵ
    Numeric TotalEquity;                    // ̼ۼʲ
    Numeric TurtleUnits;                    // ׵λ
    NumericSeries DonchianHi;               // 氲ͨϹ죬Ӻ1Bar
    NumericSeries DonchianLo;               // 氲ͨ¹죬Ӻ1Bar
    NumericSeries fsDonchianHi;             // 氲ͨϹ죬Ӻ1Bar
    NumericSeries fsDonchianLo;             // 氲ͨ¹죬Ӻ1Bar
    Numeric ExitHighestPrice;               // ʱжҪN߼
    Numeric ExitLowestPrice;                // ʱжҪNͼ
    Numeric myEntryPrice;                   // ּ۸
    Numeric myExitPrice;                    // ƽּ۸
    Bool SendOrderThisBar(False);           // ǰBarй
    NumericSeries preEntryPrice(0);         // ǰһοֵļ۸
    BoolSeries PreBreakoutFailure(false);   // ǰһͻǷʧ
Begin
    // Ͼ۹
    if (!CallAuctionFilter()) return;

    If(BarStatus == 0)
    {
        preEntryPrice = InvalidNumeric;
        PreBreakoutFailure = false;
    }

    MinPoint = MinMove*PriceScale;
    AvgTR = XAverage(TrueRange,ATRLength);
    N = AvgTR[1];
    TotalEquity = Portfolio_CurrentCapital() + Portfolio_UsedMargin();
    TurtleUnits = (TotalEquity*RiskRatio/100) /(N * ContractUnit()*BigPointValue());
    TurtleUnits = IntPart(TurtleUnits); // Сȡ

    DonchianHi = HighestFC(High[1],boLength);
    DonchianLo = LowestFC(Low[1],boLength);

    fsDonchianHi = HighestFC(High[1],fsLength);
    fsDonchianLo = LowestFC(Low[1],fsLength);

    ExitLowestPrice = LowestFC(Low[1],teLength);
    ExitHighestPrice = HighestFC(High[1],teLength);

    Commentary("N="+Text(N));
    Commentary("preEntryPrice="+Text(preEntryPrice));
    Commentary("PreBreakoutFailure="+IIFString(PreBreakoutFailure,"True","False"));

    // ʹùʹùΪPreBreakoutFailureΪTrueк
    If(MarketPosition == 0 && ((!LastProfitableTradeFilter) Or (PreBreakoutFailure)))
    {
        // ͻƿ
        If(High > DonchianHi && TurtleUnits >= 1)
        {
            // ּ۸ȡͻϹ+һλ߼֮ĽСֵܸӽʵܾ֤ɽ
            myEntryPrice = min(high,DonchianHi + MinPoint);
            myEntryPrice = IIF(myEntryPrice < Open, Open,myEntryPrice); // յʱÿ̼۴
            preEntryPrice = myEntryPrice;
            Buy(TurtleUnits,myEntryPrice);
            SendOrderThisBar = True;
            PreBreakoutFailure = False;
        }

        If(Low < DonchianLo && TurtleUnits >= 1)
        {
            // ּ۸ȡͻ¹-һλͼ֮Ľϴֵܸӽʵܾ֤ɽ
            myEntryPrice = max(low,DonchianLo - MinPoint);
            myEntryPrice = IIF(myEntryPrice > Open, Open,myEntryPrice); // յʱÿ̼۴
            preEntryPrice = myEntryPrice;
            SendOrderThisBar = True;
            SellShort(TurtleUnits,myEntryPrice);
            SendOrderThisBar = True;
            PreBreakoutFailure = False;
        }
    }

    // ͻƿ Failsafe Breakout point
    If(MarketPosition == 0)
    {
        Commentary("fsDonchianHi="+Text(fsDonchianHi));
        If(High > fsDonchianHi && TurtleUnits >= 1)
        {
            // ּ۸ȡͻϹ+һλ߼֮ĽСֵܸӽʵܾ֤ɽ
            myEntryPrice = min(high,fsDonchianHi + MinPoint);
            myEntryPrice = IIF(myEntryPrice < Open, Open,myEntryPrice); // յʱÿ̼۴
            preEntryPrice = myEntryPrice;
            Buy(TurtleUnits,myEntryPrice);
            SendOrderThisBar = True;
            PreBreakoutFailure = False;
        }

        Commentary("fsDonchianLo="+Text(fsDonchianLo));
        If(Low < fsDonchianLo && TurtleUnits >= 1)
        {
            // ּ۸ȡͻ¹-һλͼ֮Ľϴֵܸӽʵܾ֤ɽ
            myEntryPrice = max(low,fsDonchianLo - MinPoint);
            myEntryPrice = IIF(myEntryPrice > Open, Open,myEntryPrice); // յʱÿ̼۴
            preEntryPrice = myEntryPrice;
            SellShort(TurtleUnits,myEntryPrice);
            SendOrderThisBar = True;
            PreBreakoutFailure = False;
        }
    }

    If(MarketPosition == 1) // жֵ
    {
        Commentary("ExitLowestPrice="+Text(ExitLowestPrice));
        If(Low < ExitLowestPrice)
        {
            myExitPrice = max(Low,ExitLowestPrice - MinPoint);
            myExitPrice = IIF(myExitPrice > Open, Open,myExitPrice); // յʱÿ̼۴
            Sell(0,myExitPrice);    // 0½ȫƽ
        }Else
        {
            If(preEntryPrice!=InvalidNumeric && TurtleUnits >= 1)
            {
                If(Open >= preEntryPrice + 0.5*N) // ̾ͳ趨1/2N,ֱÿ̼֡
                {
                    myEntryPrice = Open;
                    preEntryPrice = myEntryPrice;
                    Buy(TurtleUnits,myEntryPrice);
                    SendOrderThisBar = True;
                }

                while(High >= preEntryPrice + 0.5*N) // ߼Ϊ׼жܽм
                {
                    myEntryPrice = preEntryPrice + 0.5 * N;
                    preEntryPrice = myEntryPrice;
                    Buy(TurtleUnits,myEntryPrice);
                    SendOrderThisBar = True;
                }
            }

            // ָֹ
            If(Low <= preEntryPrice - 2 * N && SendOrderThisBar == false) // ӲBarֹ
            {
                myExitPrice = preEntryPrice - 2 * N;
                myExitPrice = IIF(myExitPrice > Open, Open,myExitPrice); // յʱÿ̼۴
                Sell(0,myExitPrice); // 0½ȫƽ
                PreBreakoutFailure = True;
            }
        }
    }Else If(MarketPosition ==-1) // пղֵ
    {
        // ֿղʱеȽֵ
        Commentary("ExitHighestPrice="+Text(ExitHighestPrice));
        If(High > ExitHighestPrice)
        {
            myExitPrice = Min(High,ExitHighestPrice + MinPoint);
            myExitPrice = IIF(myExitPrice < Open, Open,myExitPrice); // յʱÿ̼۴
            BuyToCover(0,myExitPrice);    // 0½ȫƽ
        }Else
        {
            If(preEntryPrice!=InvalidNumeric && TurtleUnits >= 1)
            {
                If(Open <= preEntryPrice - 0.5*N) // ̾ͳ趨1/2N,ֱÿ̼֡
                {
                    myEntryPrice = Open;
                    preEntryPrice = myEntryPrice;
                    SellShort(TurtleUnits,myEntryPrice);
                    SendOrderThisBar = True;
                }

                while(Low <= preEntryPrice - 0.5*N) // ͼΪ׼жܽм
                {
                    myEntryPrice = preEntryPrice - 0.5 * N;
                    preEntryPrice = myEntryPrice;
                    SellShort(TurtleUnits,myEntryPrice);
                    SendOrderThisBar = True;
                }
            }

            // ָֹ
            If(High >= preEntryPrice + 2 * N &&SendOrderThisBar==false) // ӲBarֹ
            {
                myExitPrice = preEntryPrice + 2 * N;
                myExitPrice = IIF(myExitPrice < Open, Open,myExitPrice); // յʱÿ̼۴
                BuyToCover(0,myExitPrice); // 0½ȫƽ
                PreBreakoutFailure = True;
            }
        }
    }
End

//------------------------------------------------------------------------
// 汾 GS2016.12.18
// Ȩ TradeBlazer Software 20032017
//  TradeBlazer SoftwareTradeBlazerƽ
//          ̨ÿһ汾TradeBlazerʽ޸ĺдȨ
//------------------------------------------------------------------------
